corelang/build/rtsgame/map.core

MAP_CurrentMap: MAP_Map

MAP_PATH_SEARCHING :: 0
MAP_PATH_REACHED :: 1
MAP_PATH_UNREACHABLE :: 2

MAP_TILE_BLOCKER :: 1
MAP_TILE_ACTOR_IS_STANDING :: 2

MAP_Tile :: int
MAP_Map :: struct
  data: *MAP_Tile
  x: int
  y: int
  actors: Array(MAP_Actor)

MAP_Actor :: struct
  p: V2I
  target_p: V2I
  map: *MAP_Map

  open_paths: Array(MAP_Path)
  close_paths: Array(MAP_Path)
  tiles_visited: Array(V2I)
  history: Array(MAP_Path)

MAP_Path :: struct
  value_to_sort_by: int // distance from target
  p: V2I
  came_from: V2I

MAP_Rectangle :: (p: V2I): Rectangle
  result := Rectangle{p.x->F32 * RectX, p.y->F32 * RectY, RectX, RectY}
  return result

MAP_Circle :: (p: V2I): Vector2
  result := Vector2{p.x->F32 * RectX + RectX/2, p.y->F32 * RectY + RectY/2}
  return result

MAP_ScreenToMap :: (p: Vector2): V2I
  p0 := p.x / RectX
  p1 := p.y / RectY
  result := V2I{p0->int, p1->int}
  return result

MAP_AddActor :: (map: *MAP_Map, p: V2I): *MAP_Actor
  Add(&map.actors, {p, p, map})
  Assert(map.data[p.x + p.y * map.x] == 0)
  map.data[p.x + p.y * map.x] |= MAP_TILE_ACTOR_IS_STANDING
  actor := GetLast(&MAP_CurrentMap.actors)
  return actor

MAP_ActorSetP :: (actor: *MAP_Actor, p: V2I)
  map := actor.map
  new_tile := map.data + p.x + p.y * map.x
  if *new_tile != 0 ;; return

  tile := map.data + actor.p.x + actor.p.y * map.x
  Assert((*tile & MAP_TILE_ACTOR_IS_STANDING) != 0)
  *tile &= ~MAP_TILE_ACTOR_IS_STANDING

  *new_tile |= MAP_TILE_ACTOR_IS_STANDING
  actor.p = p

  Reset(&actor.tiles_visited)
  Reset(&actor.history)
  Reset(&actor.open_paths)
  Reset(&actor.close_paths)

MAP_SetTargetP :: (s: *MAP_Actor, p: V2I)
  s.target_p = p
  Reset(&s.tiles_visited)
  Reset(&s.history)
  Reset(&s.open_paths)
  Reset(&s.close_paths)

MAP_GetRandomP :: (m: *MAP_Map): V2I
  result := V2I{GetRandomValue(0, MAP_CurrentMap.x - 1), GetRandomValue(0, MAP_CurrentMap.y - 1)}
  return result

MAP_GetRandomUnblockedP :: (m: *MAP_Map): V2I
  for i := 0, i < 128, i += 1
    p := MAP_GetRandomP(m)
    if m.data[p.x + p.y * m.x] == 0
      return p

  Assert(false, "Invalid codepath")
  r: V2I; return r

MAP_Init :: ()
  MAP_CurrentMap.x = WinX / RectX
  MAP_CurrentMap.y = WinY / RectY
  bytes := sizeof(MAP_Tile) * MAP_CurrentMap.x->U64 * MAP_CurrentMap.y->U64
  MAP_CurrentMap.data = malloc(bytes)
  memset(MAP_CurrentMap.data, 0, bytes)

  actor := MAP_AddActor(&MAP_CurrentMap, MAP_GetRandomUnblockedP(&MAP_CurrentMap))
  actor.target_p = MAP_GetRandomUnblockedP(&MAP_CurrentMap)

  actor2 := MAP_AddActor(&MAP_CurrentMap, MAP_GetRandomUnblockedP(&MAP_CurrentMap))
  actor2.target_p = MAP_GetRandomUnblockedP(&MAP_CurrentMap)

MAP_RandomizeActors :: ()
  map := &MAP_CurrentMap
  for i := 0, i < map.actors.len, i += 1
    it := map.actors.data + i
    p := MAP_GetRandomUnblockedP(&MAP_CurrentMap)
    MAP_ActorSetP(it, p)
    it.target_p = MAP_GetRandomUnblockedP(&MAP_CurrentMap)

MAP_InsertOpenPath :: (s: *MAP_Actor, p: V2I, came_from: V2I, ignore_blocks: bool = false)
  if p.x < 0 || p.x >= s.map.x ;; return
  if p.y < 0 || p.y >= s.map.y ;; return
  if ignore_blocks == false && s.map.data[p.x + p.y * s.map.x] != 0 ;; return

  for i := 0, i < s.close_paths.len, i += 1
    it := s.close_paths.data + i
    if it.p.x == p.x && it.p.y == p.y ;; return

  for i := 0, i < s.open_paths.len, i += 1
    it := s.open_paths.data + i
    if it.p.x == p.x && it.p.y == p.y ;; return

  dx := s.target_p.x - p.x
  dy := s.target_p.y - p.y
  d  := dx*dx + dy*dy
  InsertSortedDecreasing(&s.open_paths, {d, p, came_from})

MAP_GetCloseP :: (s: *MAP_Actor, p: V2I): *MAP_Path
  for i := 0, i < s.close_paths.len, i += 1
    it := s.close_paths.data + i
    if it.p.x == p.x && it.p.y == p.y ;; return it

  Assert(false, "Invalid codepath")
  return 0

MAP_RecomputeHistory :: (s: *MAP_Actor)
  if s.close_paths.len > 1
    Reset(&s.history)
    it := GetLast(&s.close_paths)
    Add(&s.history, *it)
    for i := 0,,i += 1
      if it.p.x == s.p.x && it.p.y == s.p.y ;; break
      if i > 512
        Reset(&s.history)
        break
      it = MAP_GetCloseP(s, it.came_from)
      Add(&s.history, *it)
    Pop(&s.history)

MAP_MoveTowardsTarget :: (s: *MAP_Actor)
  tile := s.map.data + s.p.x + s.p.y * s.map.x
  if s.history.len > 0
    step := Pop(&s.history)
    new_tile := s.map.data + step.p.x + step.p.y * s.map.x
    if *new_tile == 0
      Add(&s.tiles_visited, s.p)
      s.p = step.p
      *tile &= ~MAP_TILE_ACTOR_IS_STANDING
      *new_tile |= MAP_TILE_ACTOR_IS_STANDING

MAP_PathFindUpdate :: (map: *MAP_Map)
  for actor_i := 0, actor_i < map.actors.len, actor_i += 1
    s := map.actors.data + actor_i
    for i := 0, i < s.history.len, i += 1
      it := s.history.data + i

      tile := s.map.data[it.p.x + it.p.y * s.map.x]
      if tile != 0
        Reset(&s.open_paths)
        Reset(&s.close_paths)
        Reset(&s.history)
        break

    MAP_PathFind(s)

MAP_PathFindStep :: (s: *MAP_Actor, compute_history: bool = true): bool
  if s.open_paths.len == 0
    // Reset if we didnt find solution
    if s.close_paths.len != 0
      last := GetLast(&s.close_paths)
      reached_target := last.p.x == s.target_p.x && last.p.y == s.target_p.y
      if reached_target == false
        Reset(&s.open_paths)
        Reset(&s.close_paths)
        Reset(&s.history)

    MAP_InsertOpenPath(s, s.p, s.p, ignore_blocks = true)

  if s.close_paths.len != 0
    last := GetLast(&s.close_paths)
    reached_target := last.p.x == s.target_p.x && last.p.y == s.target_p.y
    if reached_target
      return true

  it := Pop(&s.open_paths)
  Add(&s.close_paths, it)


  // @language_todo: Add continue keyword
  // if x == 0 && y == 0 ;; continue

  for y := -1, y <= 1, y += 1
    for x := -1, x <= 1, x += 1
      if (x == 0 && y == 0) == false
        p := V2I{it.p.x + x, it.p.y + y}
        MAP_InsertOpenPath(s, p, it.p)

  if compute_history ;; MAP_RecomputeHistory(s)
  return false

MAP_PathFind :: (s: *MAP_Actor)
  for i := 0, i < 32, i += 1
    done := MAP_PathFindStep(s, false)
    if done ;; break
  MAP_RecomputeHistory(s)