#import "Math.core"

Vec3   :: struct                   ;; x: F32; y: F32; z: F32
Length :: (a: Vec3): F32           ;; return sqrtf(a.x*a.x + a.y*a.y + a.z*a.z)
Negate :: (a: Vec3): Vec3          ;; return {-a.x, -a.y, -a.z}
Dot    :: (a: Vec3, b: Vec3): F32  ;; return a.x*b.x + a.y*b.y + a.z*b.z
"*"    :: (a: Vec3, b: Vec3): Vec3 ;; return {a.x*b.x, a.y*b.y, a.z*b.z}
"*"    :: (a: Vec3, b: F32) : Vec3 ;; return {a.x*b, a.y*b, a.z*b}
"*"    :: (a: F32, b: Vec3) : Vec3 ;; return {a*b.x, a*b.y, a*b.z}
"-"    :: (a: Vec3, b: Vec3): Vec3 ;; return {a.x-b.x, a.y-b.y, a.z-b.z}
"-"    :: (a: Vec3, b: F32) : Vec3 ;; return {a.x-b, a.y-b, a.z-b}
"-"    :: (a: F32, b: Vec3) : Vec3 ;; return {a-b.x, a-b.y, a-b.z}
"+"    :: (a: Vec3, b: Vec3): Vec3 ;; return {a.x+b.x, a.y+b.y, a.z+b.z}
"+"    :: (a: Vec3, b: F32) : Vec3 ;; return {a.x+b, a.y+b, a.z+b}
"+"    :: (a: F32, b: Vec3) : Vec3 ;; return {a+b.x, a+b.y, a+b.z}
"/"    :: (a: Vec3, b: Vec3): Vec3 ;; return {a.x/b.x, a.y/b.y, a.z/b.z}
"/"    :: (a: Vec3, b: F32) : Vec3 ;; return {a.x/b, a.y/b, a.z/b}
"/"    :: (a: F32, b: Vec3) : Vec3 ;; return {a/b.x, a/b.y, a/b.z}

Cross :: (a: Vec3, b: Vec3): Vec3
  result := Vec3{
    a.y * b.z - a.z * b.y,
    a.z * b.x - a.x * b.z,
    a.x * b.y - a.y * b.x,
  }
  return result

Normalize :: (a: Vec3): Vec3
  length := Length(a)
  result := a / length
  return result

Reflect :: (a: Vec3, normal: Vec3): Vec3
  an := Dot(a, normal)*2
  result := a - a * an
  return result

ConvertToARGB :: (a: Vec3): U32
  a.x = F32_Clamp(0, a.x, 1)
  a.y = F32_Clamp(0, a.y, 1)
  a.z = F32_Clamp(0, a.z, 1)
  r := (a.x * 255)->U32 << 16
  g := (a.y * 255)->U32 << 8
  b := (a.z * 255)->U32 << 0
  result := r | g | b
  return result