#import "base.kl"
#import "gdi32.kl"
#import "user32.kl"
#import "os.kl"
#import "Windows.kl"

process_heap: HANDLE
allocate :: (size: U64): *void
  if process_heap == 0
    process_heap = GetProcessHeap()
  return HeapAlloc(process_heap, 0, size)

test_unicode :: (arena: *Arena)
  string := "    豈 更 車 賈 滑 串 句 龜 龜 契 金 喇 奈 懶 癩 羅 蘿 螺 裸 邏 樂 洛 烙 珞 落 酪 駱 亂 卵 欄 爛 蘭 鸞 嵐 濫 藍 襤 拉 臘 蠟 廊 朗 浪 狼 郎 來 冷 勞 擄 櫓 爐 盧 老 蘆 虜 路 露 魯 鷺 碌 祿 綠 菉 錄 鹿 論 壟 弄 籠 聾 牢 磊 賂 雷 壘 屢 樓 淚 漏 累 縷 陋 勒 肋 凜 凌 稜 綾 菱 陵 讀 拏 樂 諾 丹 寧 怒 率 異 北 磻 便 復 不 泌 數 索 參 塞 省 葉 說 殺 辰 沈 拾 若 掠 略 亮 兩 凉 梁 糧 良 諒 量 勵 ..."
  string_result := string_to_string16(arena, string)
  print(string_result)

  s32, s32_len := utf8_to_utf32(&"A"[0], 1)
  assert(s32 == 'A, "Invalid decode") // '

  s32_2, s32_len_2 := utf8_to_utf32(&"ć"[0], 2)
  assert(s32_2 == 0x107, "Invalid decode")

  s32_3, s32_len_3 := utf8_to_utf32(&"ó"[0], 2)
  assert(s32_3 == 0xF3, "Invalid decode")

Vec2I :: struct;; x: S64; y: S64
Vec2  :: struct;; x: F32; y: F32
Windows_Bitmap :: struct
  size: Vec2I
  data: *U32
  hdc: HDC
  dib: HBITMAP

Bitmap :: struct
  size: Vec2I
  data: *U32

create_bitmap :: (size: Vec2I, bottom_up: Bool = true): Windows_Bitmap
  result: Windows_Bitmap = {size = size}
  if bottom_up == false
    result.size.y = -result.size.y

  bminfo := BITMAPINFO{
    BITMAPINFOHEADER{
      biSize          = 40, // @todo!!! size_of(BITMAPINFOHEADER),
      biWidth         = size.x->LONG,
      biHeight        = size.y->LONG,
      biPlanes        = 1,
      biBitCount      = 32,
      biCompression   = BI_RGB,
      biXPelsPerMeter = 1,
      biYPelsPerMeter = 1,
    }
  }

  hdc := GetDC(0)
  result.dib = CreateDIBSection(hdc, &bminfo, DIB_RGB_COLORS, (&result.data)->**void, 0, 0)
  result.hdc = CreateCompatibleDC(hdc)
  return result

app_is_running := true
window_procedure :: (hwnd: HWND, msg: UINT, wparam: WPARAM, lparam: LPARAM): LRESULT
  if msg == WM_DESTROY
    PostQuitMessage(0)
    app_is_running = false
    return 0
  else;; return DefWindowProcW(hwnd, msg, wparam, lparam)

WinMain :: (hInstance: HINSTANCE, hPrevInstance: HINSTANCE, lpCmdLine: LPSTR, nShowCmd: int): int
  arena: Arena
  window_name := string_to_string16(&arena, "Have a wonderful day! 豈 更 車 賈 滑 串 句 龜 ")
  w := WNDCLASSW{
    lpfnWndProc   = window_procedure,
    hInstance     = hInstance,
    lpszClassName = window_name.str,
  }
  assert(RegisterClassW(&w) != 0)

  screen_size: Vec2I = {1280, 720}
  window := CreateWindowExW(
    dwExStyle = 0, hWndParent = 0, hMenu = 0, lpParam = 0,
    X = CW_USEDEFAULT, Y = CW_USEDEFAULT, nWidth = screen_size.x->int, nHeight = screen_size.y->int,
    lpClassName = window_name.str,
    lpWindowName = window_name.str,
    dwStyle = WS_OVERLAPPEDWINDOW,
    hInstance = hInstance
  )
  assert(window != 0)
  ShowWindow(window, nShowCmd)

  window_dc := GetDC(window)
  bitmap := create_bitmap(screen_size)
  for app_is_running
    msg: MSG
    for PeekMessageW(&msg, window, 0, 0, PM_REMOVE) > 0
      TranslateMessage(&msg)
      DispatchMessageW(&msg)

    for y := 0, y < bitmap.size.y, y+=1
      for x := 0, x < bitmap.size.x, x+=1
        bitmap.data[x + y*bitmap.size.x] = 0xFFFF0000

    SelectObject(bitmap.hdc, bitmap.dib)
    BitBlt(window_dc, 0, 0, (bitmap.size.x)->int, (bitmap.size.y)->int, bitmap.hdc, 0, 0, SRCCOPY)